فائل:Confidence interval area.png

 // Scilab script for Confidence interval
 function [y]=normpdf(x)
 y=1/sqrt(2*%pi)*exp(-x.^2/2);
 endfunction
 //
 MAX=3.5;
 x=[-MAX:.1:MAX]; // X-axis values
 y=normpdf(x); // normal pdf (Y-axis)
 Pth=1.960; // threshold
//
 // polygon for the right red region
 x1=[Pth:.1:MAX];
 y1=normpdf(x1);
 x2=[x1 x1(1)];
 y2=[y1 y1(length(y1))];
 //
 // polygon for the left red region
 //x3=[-MAX:.1:-Pth];
 x3=-x1(length(x1):-1:1);
 y3=normpdf(x3);
 x4=[x3 x3(length(x3))];
 y4=[y3 y3(1)];
 //
 x5=[-Pth:.1:Pth];
 y5=normpdf(x5);
 x6=[x5  Pth -Pth];
 y6=[y5  0 0];
 //
 // marker for the threshold
 format("v",10);
 plot([Pth Pth],[0 .3],'--m');
 xstring(Pth,.31,["x_c =" string(Pth)]);
 plot([-Pth -Pth],[0 .3],'--m');
 xstring(-Pth-.5,.31,["-x_c =" string(-   Pth)]);
 //
 format("v",6);
 xset('color',2);
 xfpoly(x6,y6);
 xset('color',5);
 xfpoly(x2,y2); // draw the right filled polygon
 xfpoly(x4,y4); // draw the left filled polygon
 xset('color',1);
 plot(x,y); // draw the normal pdf curve
 //
 // area under the curve in the right red filled polygon
 Area=erfc(Pth/sqrt(2))/2;
 xstring(0,0,["area=" string(Area)]);
 text=gce();//get the handle for the text string
 text.data=[2.5,.02];
 xstring(0,0,["area=" string(Area)]);
 text=gce();//get the handle for the text string
 text.data=[-3.8,.02];
 text.foreground=5;
 //
 xstring(0,0,["C = Area =" string(1-2*Area)]);
 text=gce();
 text.data=[-.5,.41];
 text.foreground=3;
 title('standard normal probability density function');
 a=get("current_axes");//get the handle of the newly created axes
 a.data_bounds=[-4,0;4,.45];